천문학 - 음력-양력 상호 변환 함수 모듈에 관한 간단한 설명 6

이번 글에서는 음력을 양력으로 변환하는 함수와 음양력 변환에 쓰는 보조함수에 대하여 설명하겠습니다. 양력을 음력으로 바꾸는 함수는 다소 긴 설명이 필요하므로 마지막 편에서 다루도록 하겠습니다. 이 글에서 다룰 함수는 다음 3개 입니다.

Sol2Lun: 양력 날짜에서 음력 날짜를 구하는 함수
Lun2Sol: 음력 날짜에서 양력 날짜를 구하는 함수
InvLuniSolarCal: 음력 날짜를 율리우스 적일로 바꾸는 함수

1. 음양력 변환 함수를 위한 보조함수

음양력 변환함수를 편리하게 쓰기 위한 함수입니다. 여기에는 2개의 함수를 사용합니다. 이 모듈에서 음력을 양력으로, 양력을 음력으로 변환할 때에는 율리우스 적일로 결과를 출력합니다. 율리우스적일은 실생활에서 쓰기에 불편하므로, 이를 상용력으로 출력하도록 바꾸어주는 함수입니다. 양력은 1582년 10월 4일 이전은 율리우스력, 1582년 10월 15일부터는 그레고리력입니다.

(1) Sol2Lun(Y, M, D)

양력을 음력으로 바꾸어 출력하는 함수입니다. Y는 양력 연도, M은 양력 월, D는 양력일입니다. 결과는 YYYY-MM-DD 형태의 음력으로 축력하며, 윤달일 경우 "(윤)" 표시가 붙습니다.

함수 내용 중에 If Y > 1910 Then timezone = 9 Else timezone = 8 부분은 시간권을 지정해주는 부분입니다. 1910년 이전은 중국력에 날짜를 맞추는 경우가 많았기 때문에 중국의 시간권인 +8시간으로 지정해주었고, 그 이후는 현재까지 쓰고있는 시간권인 +9시간으로 설정합니다.

Public Function Sol2Lun(ByVal Y As Integer, ByVal M As Integer, ByVal D As Integer) As String
Dim ly As Integer, lm As Byte, LD As Byte, ll As Boolean, jd As Double

jd = JULIANDAY(CDbl(Y), CDbl(M), CDbl(D))
If Y > 1910 Then timezone = 9 Else timezone = 8 '시간권 설정
Call LuniSolarCal(jd, ly, lm, LD, ll)
Sol2Lun = Trim$(Str(ly)) & "-" & Trim$(Str(lm)) & "-" & Trim$(Str(LD)) & IIf(ll, "(윤)", "")
End Function

(2) Lun2Sol(Y, M, D, Leap)

이 함수는 음력을 양력으로 바꾸어주는 역할을 한다는 점을 빼면 Sol2Lun와 거의 같습니다. Y, M, D는 음력 연, 월, 일이고 Leap는 윤달 여부입니다. 윤달일 때 참값을 갖게 됩니다.

Public Function Lun2Sol(ByVal Y As Integer, ByVal M As Integer, ByVal D As Integer, ByVal Leap As Boolean) As String
Dim jd As Double, x As Boolean, A As Double, B As Double, c As Double

If Y > 1910 Then timezone = 9 Else timezone = 8 '시간권 설정
x = InvLuniSolarCal(Y, M, D, Leap, jd)
If x Then
InvJD jd, A, B, c
Lun2Sol = Trim$(Str(CInt(A))) & "-" & Trim$(Str(CInt(B))) & "-" & Trim$(Str(CInt(c)))
Else
Lun2Sol = ""
End If
End Function

2. 음력을 양력으로 바꾸어주는 함수

음력을 양력으로 환산하는 작업은 꽤 까다롭습니다. 그래서 여기에서는 음력날짜를 그대로 양력날짜로 가정하고, 반복 연산을 통해 정확한 양력 날짜를 찾아내는 방식으로 변환을 합니다.

(1) InvLuniSolarCal(LunarYear, LunarMon, LunarDay, IsLeap, JD)

InvLuniSolarCal 함수는 입력값으로 음력 연도(LunarYear), 음력 월(LunarMon), 음력 일(LunarDay)을 받아서, 긍 해당하는 율리우스적일(JD)를 출력합니다. 함수 자체의 반환값은 참과 거짓인데 입력받은 음력날짜에 해당하는 날이 있으면 참, 없으면 거짓을 출력합니다. 예를들어 음력 2012년 12월 13일(윤)을 입력하면 이 날은 실제로 존재하지 않으므로 거짓을 출력합니다.

InvLuniSolarCal 함수는 직접 음력을 양력으로 환산하는 함수는 아닙니다. 최초에 근사값을 하나 정한 다음, 양력을 음력으로 바꿔주는 함수인 LuniSolarCal 함수를 이용해서 점점 실제값에 가까운 값은 찾아가는 방식으로 계산을 합니다.

이 함수는 다음과 같은 몇가지 특성에 착안하여 설계하였습니다.

1) 음력날짜는 같은 월와 일 이름을 가지는 양력 날짜에 비하여 보통 20~30일 정도 늦게 나타난다.

2) 윤달은 같은 월와 일 이름을 가지는 양력 날짜에 비하여 보통 40~50일 정도 늦게 나타난다.

3) 음력 날짜에 1과 2의 조건을 넣어 양력의 근사값을 만들면 근사값에서 2~3개월 이내의 범위에서 입력한 음력에 대응하는 정확한 양력일을 찾을 수 있다.

이 3가지 특성을 바탕으로 최초의 근사값을 찾은 다음, 점차 참값에 접근하는 방식으로 작동합니다. 자세한 설명은 소스코드에 주석 형태로 달겠습니다.

Private Function InvLuniSolarCal(ByVal LunarYear As Integer, ByVal LunarMon As Byte, ByVal LunarDay As Byte, ByVal IsLeap As Boolean, jd As Double) As Boolean
Dim iJD As Double, iLY As Integer, iLM As Byte, iLD As Byte, iLM2 As Single, iLeap As Boolean, i As Integer, D1 As Double, lm2 As Single, IsValid As Boolean
Dim i2 As Integer

IsValid = False '일단 입력된 날짜를 존재하지 않는 음력 날짜로 가정(참값을 찾기 전이므로)

'입력한 음력에 대응하는 첫 근사값 구하기
iJD = JULIANDAY(CDbl(LunarYear), CDbl(LunarMon), CDbl(LunarDay)) '먼저 음력날짜를 양력날짜와 같다고 가정하고 그대로 율리우스 적일을 구함(초기근사).
iJD = iJD + 25: lm2 = LunarMon '윤달이 아닐 경우 1의 값에 25일을 더함.
If IsLeap Then iJD = iJD + 25: lm2 = lm2 + 0.5 '윤달이면 여기에 다시 25일을 더함(양력 날짜보다 50일이 늦다고 가정). lm2에는 윤달이 평달보다 늦음을 표시하기 위해 0.5를 더함.

If LunarYear < 1582 Then iJD = iJD + Int(0.0078 * (1582 - LunarYear)) '율리우스력의 오차를 조절하기 위한 보정항을 계산하여 근사값에 더함.

i = 0
Do '근사값으로 구한 양력일이 실제로 입력한 음력일이 맞는지 확인.
LuniSolarCal iJD, iLY, iLM, iLD, iLeap '근사값의 음력일 계산

If iLY > LunarYear Then '연도가 같은지 비교. 다르면 30일씩 더하거나 빼면서 다시 계산
iJD = iJD - 30
ElseIf iLY < LunarYear Then
iJD = iJD + 30
ElseIf iLY = LunarYear Then
i2 = 0
Do
LuniSolarCal iJD, iLY, iLM, iLD, iLeap
iLM2 = iLM + IIf(iLeap, 0.5, 0) '윤달 여부를 표시

If iLM2 > lm2 Or iLY > LunarYear Then '월이 같은지 비교. 다르면 10일씩 더하거나 빼면서 다시 계산
iJD = iJD - 10
ElseIf iLM2 < lm2 Or iLY < LunarYear Then
iJD = iJD + 10
ElseIf iLM2 = lm2 Then
D1 = iJD - iLD '연과 월이 모두 같으면, D1에 해당 음력 달 0일의 위치를 저장
IsValid = True '입력한 음력날이 있으므로 참값 출력
End If
i2 = i2 + 1
Loop Until iLM2 = lm2 Or i2 > 15 '음력월 탐색은 연도가 같다면 150일 안쪽 범위에서만 탐색
End If
i = i + 1
Loop Until iLY = LunarYear Or i > 10 '음력 연도 탐색은 300일 범위 이내에서만 수행.

jd = D1 + LunarDay '음력월 0일의 날짜에 입력한 날짜를 더하여 해당일의 율리우스 적일을 출력
InvLuniSolarCal = IsValid
End Function